Terraform Provider

With the CloudCasa Terraform Provider, you can use Terraform to configure cluster, backup job, policy, and storage resources in CloudCasa. You can also automatically deploy the CloudCasa agent to Kubernetes clusters. The provider interacts with the CloudCasa service using CloudCasa’s published REST APIs.

Getting Started

The CloudCasa Terraform Provider can be obtained from HashiCorp’s Terraform Registry.

Typically, the provider might be used to automatically add a new Kubernetes cluster to CloudCasa and configure backups for it as part of the cluster provisioning process. But there are other use cases for it as well. Below is an example of how to initialize the provider and use it to install the CloudCasa agent and take a snapshot backup.

Initializing the Provider

In your Terraform manifest, create and configure the provider:

terraform {
  required_providers {
    cloudcasa = {
      version = "1.2.1"
      source = "catalogicsoftware/cloudcasa"
    }
  }
}

provider "cloudcasa" {
  apikey = "API_KEY_HERE"

  # Optional: For Selfhosted CloudCasa, set server URL
  # cloudcasa_url = "https://cloudcasa.example.com"
  # Optional: allow insecure TLS connections to CloudCasa server
  # insecure_tls = true
}

Creating CloudCasa Resources

Kubecluster

A cloudcasa_kubecluster resource represents a Kubernetes cluster. You can import an existing CloudCasa cluster using terraform import or define a new cluster.

To automatically install the CloudCasa agent on a cluster set auto_install to true. The provider will apply the agent spec using the environment variable KUBECONFIG to find the cluster context.

resource "cloudcasa_kubecluster" "testcluster" {
  name = "test_terraform_cluster"

  auto_install = true
}

Objectstore

The cloudcasa_objectstore resource defines storage locations for CloudCasa backups. CloudCasa supports both AWS S3 and Azure Blob Storage as backend storage providers.

resource "cloudcasa_objectstore" "s3_example" {
  name          = "my-s3-storage"
  provider_type = "s3"
  bucket_name   = "my-backup-bucket"
  endpoint_url  = "https://s3.amazonaws.com"
  region        = "us-east-1"
  access_key    = "AKIAIOSFODNN7EXAMPLE"
  secret_key    = "wJalrXUtnFEMI/K7MDENG/bPxRfiCYEXAMPLEKEY"
}

An objectstore can be associated with a kubecluster for all backups, or with specific kubebackup resources for copy backups.

Kubebackup

The cloudcasa_kubebackup resource refers to both snapshots and copy backups. Cluster ID of a valid CloudCasa kubecluster is required.

If run_on_apply is True, the backup will be considered Adhoc and does not require a policy ID. With this setting the backup will run any time we run terraform apply, even if the backup has already been created. Terraform will wait up to 5 minutes for the job to complete.

For example, here is a simple ad hoc snapshot job:

resource "cloudcasa_kubebackup" "adhoc_snapshot_example" {
  name = "cloudcasa_adhoc_snapshot_example"
  kubecluster_id = resource.cloudcasa_kubecluster.example.id

  all_namespaces = true
  snapshot_persistent_volumes = true

  copy_persistent_volumes = false

  run_on_apply = true
}

Policy

Policies are required for backups that do not have run_on_apply set. They are created by defining a Cron schedule for the job:

resource "cloudcasa_policy" "testpolicy" {
  name = "test_terraform_policy"
  timezone = "America/New_York"
  schedules = [
    {
      retention = 30,
      cron_spec = "30 0 * * MON,FRI",
      locked = false,
    }
  ]
}

Importing Resources

You can import existing CloudCasa resources to manage them in Terraform using terraform import. For example, assume we have created a policy named “test_manual_policy” in CloudCasa UI. First create an empty resource for this policy:

resource "cloudcasa_policy" "importtest" {
  name = "test_manual_policy"   # Name of the policy resource in CloudCasa
}

Get the ID from the CloudCasa UI (or casa) and use terraform import <resource_state_path> <CC ID>:

terraform import cloudcasa_policy.importtest 64948e5160a55cbabb5625f5

After importing, Terraform will try to apply any local changes to the CloudCasa resource the next time you apply. Check the resource in Terraform using terraform state show <resource_state_path> and update the configuration values to match, and make any desired changes. Changes in Terraform will always supercede changes in CloudCasa!

For Terraform v1.4+, you can add an import block directly to the Terraform config to avoid using terraform import manually each time:

import {
  provider =
  to = cloudcasa_policy.importtest
  id = "64948e5160a55cbabb5625f5"
}
resource "cloudcasa_policy" "importtest" {
  name = "test_manual_policy"
}